/////////////////////////////////////////////////////////////////////////////////
// Copyright © 2008-2010  W. Kowarschick 
//
// Permission is granted to copy, distribute and/or modify this document
// under the terms of the WK License, Version 1.0 (WKL 1.0) or any later version 
// published by Wolfgang Kowarschick.
/////////////////////////////////////////////////////////////////////////////////

package die.model 
{

  import flash.events.Event;
  import flash.events.TimerEvent;
  import flash.utils.Timer;
  
  import wk.mvcs.model.WK_Model;

  [Bindable]
  public class ModelDie extends WK_Model implements IModelDie
  {
    /////////////////////////////////////////////////////////////////////////////
    // Private Members
    /////////////////////////////////////////////////////////////////////////////

    private var v_state: String = ConstantsDice.NO_VALUE;
    private var v_value: uint   = 0;
    private var v_timer: Timer  = 
                  new Timer(ConstantsDice.DELAY, ConstantsDice.NUMBER_OF_ROLLS);

    private function mh_timer(event: Event): void
    {
      value = Math.floor(Math.random() * 6) + 1; 
    }

    private function mh_timer_complete(event: Event): void
    {
      state = ConstantsDice.THROWN;
    }
    
    /////////////////////////////////////////////////////////////////////////////
    // Constructor
    /////////////////////////////////////////////////////////////////////////////
    
    public function ModelDie()
    {
      v_timer.addEventListener(TimerEvent.TIMER,          mh_timer);
      v_timer.addEventListener(TimerEvent.TIMER_COMPLETE, mh_timer_complete);
    }
    
    /////////////////////////////////////////////////////////////////////////////
    // Attributes
    /////////////////////////////////////////////////////////////////////////////
    
    /**
     * The state of the die: 
     * <code>ROLLING</code>, i.e., the die is currently rolling,
     * or <code>THROWN</code>, i.e., the die has been thrown 
     * and until the next throw the value does not change, 
     * or <code>NO_VALUE</code>, i.e. the die is in a box and no value
     * (0, to be more precisely) is displayed.
     */

    public function get state(): String
    {
      return v_state;
    }
    public function set state(p_state: String): void
    {
      v_state = p_state;
    }

    /**
     * The value of the die: <code>1 .. 6</code> 
     * and <code>0</code> (when <code>state == NO_VALUE</code>).
     * It can only be set if the die currently is not <code>ROLLING</code>.
     */
    public function get value(): uint
    {
      return v_value;
    }

    public function set value(p_value: uint): void
    {
      if (1 <= p_value && p_value <= 6)
        v_value = p_value;
      else if (p_value == 0)
      {
        state = ConstantsDice.NO_VALUE;
        v_value = 0;
      }
      else
        throw new Error("The value " + p_value + " is greater than 6.");
    }

    /////////////////////////////////////////////////////////////////////////////
    // Public Methods
    /////////////////////////////////////////////////////////////////////////////

    /**
     * If the die is currently not <code>ROLLING</code>, it starts 
     * <code>ROLLING</code>. For <code>NUMBER_OF_ROLLS</code> times
     * (with a delay time of <code>DELAY</code> ms after each roll)
     * a new random value is computed for the die. Thereafter the 
     * state is switched to <code>THROWN</code>.
     */
    public function rollTheDie(): void
    {
      if (v_state != ConstantsDice.ROLLING)
      {
        state = ConstantsDice.ROLLING;
        v_timer.reset();
        v_timer.start();
      };
    }
    
    /////////////////////////////////////////////////////////////////////////////
    // EOC
    /////////////////////////////////////////////////////////////////////////////
  }
} 

/////////////////////////////////////////////////////////////////////////////////
// EOF
/////////////////////////////////////////////////////////////////////////////////