Würfelauge (Flash 8)

Englische Bezeichnung des Wortes „Würfelauge“

Würfelauge (deutsch) = pip (Englisch)

Datei WK_Pip.as

Folgender Code wird in einer Datei WK_Pip.as auf dem Rechner abgelegt:

/*******************************************************************************
 * Pip (Würfelauge)
 *******************************************************************************/

class WK_Pip extends MovieClip 
{
 /******************************************************************************
  * private members
  ******************************************************************************/

  private var v_state: String = "off";
    
 /******************************************************************************
  * getter and setter methods
  ******************************************************************************/

  [Inspectable (defaultValue="off", type=String, enumeration="off,on")]
  
  public function get state(): String
  { 
    return v_state; 
  }

  public function set state(s: String): Void
  { 
     if (v_state != s)
	 {
       v_state = s;
	   this.gotoAndStop(v_state);
     }
  }

 /******************************************************************************
  * constructor
  ******************************************************************************/

  public function WK_Pip() 
  {
    super();
    this.gotoAndStop(v_state);
  }

 /******************************************************************************
  * public methods
  ******************************************************************************/

  public function switch_on(): Void
  {
    state = "on";  // Call of the setter method!
  }

  public function switch_off(): Void
  {    
    state = "off"; // Call of the setter method!
  }

 /******************************************************************************
  * EOF
  ******************************************************************************/
}

MovieClip „Würfelauge“ erzeugen

1. Neues Flash-Dokument erstellen: pip.fla; Datei im selben Ordner speichern wie Datei WK_Pip.as.
2. Ebene Ebene 1 umbenennen in l_pips („l“ = „level“).
3. Elipsenwerkzeug (Oval Tool): hellgrauen Kreis mit schwarzem Rand zeichnen (evtl. Shift-Taste gedrückt halten).
4. Auswahlwerkzeug (Selection Tool): ganzen Kreis selektieren.
5. Kreis mit Taste F8 in ein Smybol verwandeln:
   • Typ: MovieClip
   • Name: s_pip („s“ = „symbol“)
   • Erweitert:
     • Bezeichner: s_pip
     • AS 2.0-Klasse: WK_Pip
     • Häckchen nur bei Export für ActionScript
6. Rechtklick auf Bibliothek -> s_pip -> Komponentendefinition:
   • AS 2.0-Klasse: WK_Pip
   • Häckchen nur bei Optionen: Anzeige in Komponenten-Bedienfeld
   • QuickInfo-Text: pip of a dice
7. Doppelklick auf Bibliothek -> s_pip.
8. Ebene Ebene 1 umbenennen in l_pip („l“ = „level“).
9. Ebene l_labels erzeugen.
10. Bei Bild (Frame) 20 für beide Ebenen ein Bild einfügen (Rechtsklick => Bild einfügen).
11. Bei Bild (Frame) 10 für beide Ebenen ein Schlüssel-Bild einfügen (Rechtsklick => Schlüsselild einfügen).
12. Ebene l_pib aktivieren und bei Bild (Frame) 10 Inneres des Kereises rot einfärben.
13. Ebene l_labels aktivieren und bei Bild (Frame) 1 Label off sowie bei Bild 10 Label on einfügen (Eigenschaften -> <Bildmarkierung>).

MovieClip „Würfelauge“ testen

1. Ebene l_pibs im Haupt-MovieClip (_root) aktivieren.
2. Drei Objekte vom Typ s_pip erzeugen: drei Mal Bibliothek -> s_pip auf die Bühne ziehen.
3. Die drei Objekte benennen: m_pip_1, m_pip_2, m_pip_2 („m“ = „movie“): Auswahlwerkzeug (Selection Tool) => Objekt anklicken => Eigenschaften: <Instanzname> ändern.
4. Folgenden Code in erstes Bild des Haupt-Movie-Clips einfügen und Film ablaufen lassen (Strg Return):
   m_pip_1.state = "on";
m_pip_2.state = "off";
m_pip_3.state = "on";

trace(m_pip_1.state);
trace(m_pip_2.state);
trace(m_pip_3.state);

Quellen

• Kowarschick, W.: Multimedia-Programmierung

Dieser Artikel ist GlossarWiki-konform.